Because the TI-81 doesn't have a link port, you need to type in the entire game source code by hand in the PRGM editor. Because of the memory limitations you must type in the matrices as well. Now, here are the matrices content and source code you must type on the calculator below. First, the matrices. Press MATRX then left arrow and under the EDIT tab you can choose which matrix to edit. Here is the data to be entered listed below:

[A] 6x6
1,1=0
1,2=6
1,3=3
1,4=0
1,5=11
1,6=12
2,1=9
2,2=0
2,3=2
2,4=7
2,5=1
2,6=8
3,1=20
3,2=8
3,3=0
3,4=0
3,5=8
3,6=8
4,1=8
4,2=8
4,3=0
4,4=0
4,5=8
4,6=8
5,1=8
5,2=10
5,3=0
5,4=6
5,5=4
5,6=8
6,1=5
6,2=7
6,3=7
6,4=4
6,5=7
6,6=4

[B] 6x6
1,1=0
1,2=0
1,3=13
1,4=0
1,5=0
1,6=0
2,1=6.1
2,2=7
2,3=7
2,4=7
2,5=3.1
2,6=0
3,1=8
3,2=0
3,3=0
3,4=0
3,5=8
3,6=0
4,1=8
4,2=0
4,3=11
4,4=0
4,5=8
4,6=0
5,1=8
5,2=0
5,3=8
5,4=0
5,5=8
5,6=0
6,1=5
6,2=7
6,3=2
6,4=7
6,5=4
6,6=0

Now for the program files. Illusiat 81 uses all 37 programs avaliable on the TI-81 but no name were assigned to them (not that it matters, since on the 81 you run programs by their ID not their name and the game uses all 37 programs avaliable. To run the game you will run Prgm1. Here is the code you need to type on the calc. The reason why the game uses that many sub programs compared to the original is to save every byte of RAM possible by avoiding repetitive code and taking advantage of the fact that program size on a TI-81 can be minimum 0 byte instead of 12 like on the TI-83+. Note that IS>( doesn't mean the letter "I" and "S" followed by a ">" and "(" symbol. It is the IS>( instruction in the program menu. Also when you see -> it's the STO key symbol. =/= means the "not equal sign from the 2nd+MATH menu (option 2) and I will refer to the theta symbol as *Theta*. Also, in the last program you will notice the {x}( function. It is one single character accessed with 2nd then 0. Here we go now. I recommend using a monospace font to read the code below like Fixedys, Courrier or Lucida Console.

Prgm1:
ClrHome
All-Off
Grid Off
ClrDraw
5.5->Xmin
5.6->Xmax
Xmin->Ymin
Xmax->Ymax
PrgmW
Disp "  ILLUSIAT 81"
PrgmW
PrgmY
Disp "C2008 OMNIMAGA"
PrgmY
Disp "1NEW 2SAVE 3END"
Input O
ClrHome
If O=1
Prgm2
If O=2
Prgm3

Prgm2:
PrgmY
PrgmY
PrgmY
PrgmY
PrgmY
PrgmY
Disp "       8"
cos cos cos 1
PrgmY
cos cos 1
Disp "^X^  ^X^   ^X^"
cos cos 1
Disp "   ^X^ ^X^^X^"
cos cos 1
Disp " ^X^^X^     ^X^"
cos cos 1
Disp "^X^        ^X^"
Lbl 1
cos cos cos 1
PrgmY
IS>(O,9
Goto 1
ClrHome
Disp "AS YOU FLEE FROMGOONS, YOU FALL IN A HOLE."
Pause
Disp "THE BEHEMOTH    RUINS! I MUST   GET OUT!"
Pause
ClrHome
20->[A](3,1
4->[A](6,4
6.1->[B](2,1
3.1->[B](2,5
7->[B](2,3
1->L
42->C
C->M
0->I
PrgmD
1->G
Prgm3

Prgm3:
If G=10
3->G
Lbl 0
[A](Y,X->K
If I
[B](Y,X->K
1->N
1->S
1->F
1->W
If K=0
PrgmG
If K=1
PrgmH
If K=2
PrgmI
If Int K=3
PrgmJ
If K=4
PrgmK
If K=5
PrgmL
If Int K=6
PrgmM
If K=7
PrgmN
If K=8
PrgmO
If K=9
PrgmP
If K=10
PrgmQ
If K>10
PrgmR
Disp "1< 2> 3^ 4V 5XP"
Input K
ClrHome
If K=5
Prgm4
If K=/=5
PrgmC
If K=1
X-W->X
If K=2
X+F->X
If K=3
Y-N->Y
If K=4
Y+S->Y
Goto 0

Prgm4:
ClrHome
Disp "LV"
Disp L
Prgm6
Pause
ClrHome
Disp "HP/MP CAP"
Disp C
Disp "NEXT LV"
Disp P
Pause
ClrHome

Prgm5:
30GG->E
ClrHome
Disp "MONSTER!"
Round(Rand,0->T
Lbl 0
If T=0
Prgm7
If T
Prgm8
If H<1
Goto 1
If E<1
Goto 2
If T=0
1->T
If T=2
0->T
Goto 0
Lbl 1
Disp "ANNHILATED"
If G=10
3->G
If G=15
9->G
If G=30
9->G
PrgmD
Stop
Lbl 2
3+2L->V
H+V->H
If H>C
C->H
M+V->M
If M>C
C->M
P-7G->P
If P<1
PrgmF
Prgm4

Prgm6:
Disp "HP"
Disp H
Disp "MP"
Disp M

Prgm7:
Prgm6
0->D
Disp "1ATK 2LIT 3HEAL"
Input O
0
If O=1
-9LRound(Rand+1,0->D
If O=2
PrgmA
If O=3
PrgmB
If O=/=3
Prgm9

Prgm8:
Disp "GOON HITS U"
-G5Round(Rand+1,0->D
Prgm0
2->T

Prgm9:
Disp D
E+D->E

Prgm0:
H+D->H
If H<1
0->H
If H>C
C->H

PrgmA:
-(M>19)12LRound(3Rand+1,0->D
0->U
If M<20
End
Lbl 1
Disp "       >"
Disp "       Z"
Disp "       7"
Disp "       <"
IS>(U,5
Goto 1
DispGraph
M-20->M
If M<1
0->M

PrgmB:
(M>9)11LRound(2Rand+1,0->D
M-10->M
If M<1
0->M
0->U
Lbl 1
DispHome
DispGraph
Is>(U,5
Goto 1
Disp "CURED"
Prgm0

PrgmC:
Round(Rand,0
If Ans
Prgm5

PrgmD:
C->H
C->M
C->P
2->X
5->Y
If I=0
End
3->X
4->Y

PrgmE:
C+V->C
L+1->L

PrgmF:
If L<30
PrgmE
C->P

PrgmG:
PrgmX
PrgmY
PrgmY
PrgmY
PrgmY
PrgmX

PrgmH:
PrgmX
PrgmU
PrgmU
PrgmU
PrgmU
PrgmX
0->F

PrgmI:
PrgmX
PrgmY
PrgmY
PrgmY
PrgmY
PrgmW
0->S

PrgmJ:
If K=/=3.1
Goto 1
6.2->[B](2,1
3->[B](2,5
Disp "YOU HEAR A SOUNDTOTHE LEFT..."
9->G
Lbl 1
If K>3
PrgmT
PrgmW
PrgmU
PrgmU
PrgmU
PrgmU
PrgmX
0->N
0->F

PrgmK:
PrgmX
PrgmU
PrgmU
PrgmU
PrgmU
PrgmW
0->S
0->F

PrgmL:
PrgmX
PrgmV
PrgmV
PrgmV
PrgmV
PrgmW
0->S
0->W

PrgmM:
If K<6.2
Goto 1
2->[B](2,3
6.1->[B](2,1
Disp "A PATH OPENS TOPMIDDLE."
Lbl 1
If K=/=6
PrgmT
PrgmW
PrgmV
PrgmV
PrgmV
PrgmV
PrgmX
0->N
0->W

PrgmN:
PrgmW
PrgmY
PrgmY
PrgmY
PrgmY
PrgmW
0->N
0->S

PrgmO:
PrgmX
PrgmX
PrgmX
PrgmX
PrgmX
PrgmX
0->F
0->W

PrgmP:
PrgmW
PrgmV
PrgmV
PrgmV
PrgmV
PrgmW
0->N
0->S
0->W

PrgmQ:
PrgmX
PrgmX
PrgmX
PrgmX
PrgmX
PrgmW
0->S
0->F
0->W

PrgmR:
If K=20
PrgmS
If K>29
PrgmT
If K=12
PrgmZ
If K=13
Prgm*Theta*
PrgmW
PrgmX
PrgmX
PrgmX
PrgmX
PrgmX
0->N
0->F
0->W

PrgmS:
ClrHome
Disp "SWITCH OPENS"
Disp "PATH NEARBY."
30->[A](3,1
2->[A](6,4
3->G
Pause

PrgmT:
Disp "HP RESTORED"
C->H
Pause

PrgmU:
Disp "          LLLLL"

PrgmV:
Disp "LLLLL"

PrgmW:
Disp "LLLLLLLLLLLLLLL"

PrgmX:
Disp "LLLLL     LLLLL"

PrgmY:
Disp ""

PrgmZ:
10->G
2->Y
ClrHome
Disp "U WILL NOT PASS"
PrgmY
PrgmY
PrgmY
Disp "      ^X^"
Pause
Prgm5
1->I
4->Y
3->X
6->G
PrgmT

Prgm*Theta*:
2->Y
ClrHome
0->K
Lbl 1
PrgmY
IS>(K,6
Goto 1
Disp "       8"
Lbl 0
cos cos cos cos cos cos cos cos 1
PrgmY
IS>(K,9
Goto 0
ClrHome
Disp "   ^=){x}(=^"
PrgmY
PrgmY
PrgmY
Disp "       8"
cos cos cos cos cos cos cos cos 1
ClrHome
PrgmY
Disp "   ^=){X}(=^"
PrgmY
PrgmY
Disp "       8"
cos cos cos cos cos cos cos cos 1
Disp "YOU ARE DOOMED"
Pause
Disp "TO DIE IN THERE"
Pause
ClrHome
Disp "YOU WILL NOT GETOUT. REST IN    PEACE!"
Pause
15->G
Prgm5
Disp "NOW SEE MY TRUE POWER!"
Pause
30->G
Prgm5
ClrHome
Disp "YOU ESCAPED THE BEHEMOTH RUINS"
Pause
Disp "AND BROKEN THE   DEMON CURSE!"
Pause
Disp "YOU ARE NOW     SAFE!"
Pause
ClrHome
PrgmY
PrgmY
PrgmY
Disp "    THE END"
Pause
ClrHome
Stop